[bcn-pm] RS: salutacions i consulta

[Agud Pique, Enric]

Hola Marc,
 
Moltes gràcies, he probat el teu codi! en el meu cas, he preferit posar comes, sep_char => ',' 
 
Consulta de la linea 
 
open my $fh, ">:encoding(utf8)", $output_file or die $!;

normalment poseu enconding? 
 
Disculpa pel meu dubte però, aquí el outfile agafa el nom del fitxer de sortida el data-csv, i el   $fh? 
 
Gràcies
 
 
 
________________________________

De: Barcelona-pm [mailto:barcelona-pm-bounces+eagud.q=tv3.cat a pm.org] En nom de Marc Egea i Sala
Enviat: dimecres, 21 de agost de 2013 23:32
Per a: Barcelona Perl Mongers
Tema: Re: [bcn-pm] RS: salutacions i consulta


A mi el més simple que se m'acut és utilitzar LWP::Simple com i Text:CSV per fer el csv. Com diu en Xavi, aprofito que la web em deixa fer una petició get directament amb el codi que vull...
Pot ser alguna cosa així (amb una regex ultrafàcil i sense passar paràmetres) :

#!/usr/bin/env perl

use strict;
use v5.10;

use LWP::Simple;
use Text::CSV;

my $output_file = 'data.csv';
my @airports    = qw( LEBL LEGE );

open my $fh, ">:encoding(utf8)", $output_file or die $!;
my $csv = Text::CSV->new ( { binary => 1, sep_char => ';' } );

for my $code ( @airports ) {
    my $page = "http://aviationweather.gov/adds/metars/?station_ids=$code&std_trans=standard&chk_metars=on&hoursStr=most+recent+only&submitmet=Submit";
    my $html = get( $page );
    my @data = $html =~ />(.*)<\/FONT/;

    $csv->print( $fh => [ split( ' ', $data[0] ) ] );
    print $fh "\n"
}

close $fh;




El dia 21 d'agost de 2013 23.04, Xavier Noria <fxn a hashref.com> ha escrit:


	Hola Enric, 

	En aquest problema podem simplificar una mica les coses observant com va el website. Per exemple, el formulari es nomes una manera de fer una peticio GET amb un cert query string, si fas un parell de proves veus com van els parametres i aixi t'estalvies simular la navegacio (tot i que tambe es podria fer).

	Pel que fa a la resposta, es un HTML prou senzill. Per a extreure dades de documents HTML arbitraris normalment es fan anar parsers HTML, pero en aquesta pagina d'estructura coneguda es mes que suficient al meu entendre fer anar una expressio regular.

	Tambe fa mes facil la feina saber que les dades METAR son com son, una tirallonga ASCII sense massa complicacio des d'aquest punt de vista.

	Et passo un script que podria ser un punt de partida, nomes treu les dades METAR per stdout, una fila per aeroport. Rep els codis d'aeroport com a arguments:

	    perl fetch_metar.pl LEBL LEGE

	Naturalment si volguessis ajuda en modificar-lo no dubtis a escriure.

	Fa anar el modul LWP::UserAgent:

	    cpan install Bundle::LWP

	Espero que t'ajudi,

	Xavier

	use strict;
	use warnings;

	use URI;
	use LWP::UserAgent;

	my @airports = @ARGV;

	die <<EOS unless @airports;
	Si us plau, passam'm algun codi d'aeroport, com ara

	    perl $0 LEBL LEGE

	EOS

	my $url = URI->new('http://aviationweather.gov/adds/metars');
	$url->query_form(
	    station_ids => join(' ', @airports),
	    std_trans   => 'standard',
	    chk_metars  => 'on',
	    hoursStr    => 'most recent only',
	);

	my $ua  = LWP::UserAgent->new;
	my $res = $ua->get($url);

	if ($res->is_success) {
	    my $html = $res->decoded_content;

	    while ($html =~ /<FONT[^>]+>([^<]+)/g) {
	        print "$1\n";
	    } 
	} else {
	    die $res->status_line;
	}

	_______________________________________________
	llista dels Barcelona-pm
	Barcelona-pm a pm.org
	http://mail.pm.org/mailman/listinfo/barcelona-pm
	BCN Perl Mongers: http://barcelona.pm.org
	


-------------- part següent --------------
Un document HTML ha estat eliminat...
URL: <http://mail.pm.org/pipermail/barcelona-pm/attachments/20130822/66257eae/attachment-0001.html>